Interactive Media Design Review 1999/Interactive Media Design Review 1999.iso/pc/Demos/Bombardier_PC/BSCRIPTS.CST/00095_Script_subCategory

Text File | 1999-04-25 | 3KB | 140 lines

-- ⌐ 1998 @radical.media, inc. & Concurrent New Media Group, L.L.C.
-- Developed for Bombardier, Inc.
--
-- All programming developed by:
-- Robert Fabricant, Valerie Valoueva, Ossi Shaked,
-- Henry Sauvageot, Chris Howell & Chris Girand
--
-- Use of this code by parties other than @radical.media, inc. or their
--agents
-- without the express written consent of @radical.media, inc. AND Concurrent
-- New Media Group, L.L.C. is strictly prohibited.
------------------------------------------------------

property mySprite, myName, myNormal, myRoll, myHilite, myType, myGroup, lastSelected, selected, myLoc, myFrame


on new me
  global menuController


  set mySprite = the spriteNum of me
  set myNormal = the member of sprite mySprite
  set myName = the name of member myNormal
  set myRoller = myName&"-roll"
  set myHiliter = myName&"-hil"
  set myRoll = member myRoller
  set myHilite = member myHiliter
  set selected = 0
  set myLoc = the loc of sprite mySprite
  puppetsprite mySprite, true
  set the loc of sprite mySprite = point(-1000, -1000)
  set scriptNum = the scriptNum of sprite mySprite
  set myType = the name of member scriptNum
  register menuController, me, myName
  return me
end




on heresYourGroup me, theGroup
  set myGroup = theGroup
end

on setLastSelected me, theLastSelObj
  set lastSelected = theLastSelObj
end

on getType me
  return myType
end


on setFrame me, theFrame
  set myFrame = theFrame
end


-- The two rollover scripts
on mouseEnter me
  if not selected then
    puppetsound 3, "subrollOldOld"
    set the member of sprite mySprite = member myRoll
  end if
end
on mouseLeave me
  if not selected then
    set the member of sprite mySprite = member myNormal
  end if
end

on reset me
  set selected  = 1
  set the member of sprite mySprite = member myHilite
end


on mouseUp me
  global  comefromQTVR

  if selected then
    nothing
  else
    set comefromQTVR = FALSE
    set the visible of sprite 110 = TRUE
    IWasSelected lastSelected, me
    set selected = 1
    repeat with i = 1 to count(myGroup)
      set teamMate = getat(myGroup, i)
      set hisType = getType(teamMate)
      if hisType = "category" or hisType = "knob" then
        setSubCat teamMate, me
      end if
      hideYourSelf teamMate
    end repeat
    clearpups
    --    sendAllSprites(#qtvrPuppetOff, myFrame)
    go to frame myFrame
    puppetsound 3, "mouse5"
  end if
end



-- these 2 handlers are called when the submenu bar for this category needs to be either visible or not visible.
on showYourSelf me
  set the loc of sprite mySprite = myLoc
end

on hideYourSelf me
  set the loc of sprite mySprite = point(-1000,-1000)
  set the member of sprite mySprite = member myNormal
  set selected = 0

end


on deselect me
  repeat with i = 1 to count(myGroup)
    set teamMate = getat(myGroup, i)
    disable teamMate
  end repeat
end

on disable me
  set selected = 0
  set the member of sprite mySprite = member myNormal
  set the loc of sprite mySprite = point(-1000,-1000)
end

-- not called in this application, but necessary to call on menuController if the "behaviour line" is ever broken in a movie.

on endPuppeting me
  puppetSprite mySprite, false
end

on getFrame me
  return myFrame
end